;;
;; Arkadaş Bul! V1 (www.fireturk.com)
;; Coded by DefauLt (default@fireturk.com) & el33t (el33t@fireturk.com)
;;
;; Arkadaş Bul!; yüklü olduğu scripti kullananları arasında iletişim kurmayı kolaylaştıran
;; bir sistemdir. Yüklü olduğu scripti kullananlar; yaş, cinsiyet ve bulunduğu yere göre
;; tüm kullananlar arasında bir kaç saniye içinde arama yapabilir, bulduğu sonuçlarla
;; direkt iletişime geçebilir.
;; "Tamamen" bir Türk keşfidir ve Türk halkı için yapılmıştır.
;; İsteyen izin almaksızın scriptine ekleyebilir.
alias sw {
if $sock($1).status == active {
sockwrite -nt $1-
}
}
alias arkadasfnick {
return $right($gettok($1,1,33),-1)
}
alias bul {
if $dialog(arkadasbul) {
dialog -x arkadasbul
}
dialog -mad arkadasbul arkadasbul
arkadasecho 0,1 Arkadaş Bul! ile binlerce insan birbirini buluyor, tanışıyor, kaynaşıyor!
}
alias arkadasecho {
echo -s %ara $1-
}
alias arkadasbagla {
if !$sock(arkadasbul) {
sockopen arkadasbul servepeace.dyndns.org 6667
}
}
alias arkadasinput {
if $input($replace($2-,$chr(94),$crlf),y,Arkadaş Bul!) {
window -wak[0] $+(@»,$1)
}
else {
window -c $+(@»,$1)
}
}
alias arkadasbilgi {
return $hget(arkadasbul,$1)
}
alias ignoretemizle {
if $hget(arkadasbulignore) {
hfree arkadasbulignore
arkadasecho Ignore listesi temizlendi.
}
else {
arkadasecho Ignore listesi zaten boş.
}
}
on *:START: {
arkadasbagla
.timer 0 10 arkadasbagla
;; Her açılışta Arkadaş Bul! 'un otomatikman açılmasını engellemek için üstteki
;; bul yazan satırı silin ya da bul 'dan önce noktalı virgül (;) koyun.
if $dialog(arkadasbul) {
dialog -s $ifmatch 10 100 246 200
}
}
on *:INPUT:@»*: {
if $left($1,1) != / {
echo $target $timestamp < $+ $arkadasbilgi(nick) $+ > $1-
sw arkadasbul PRIVMSG $right($target,-2) : $1-
}
}
MENU @»* {
Pencereyi Temizle:clear $active
Bu kişiyi engelle: {
hadd -m arkadasbulignore $right($active,-2) $r(1,9999)
arkadasecho $right($active,-2) ignore listesine eklendi. Ignore listesini temizlemek için /ignoretemizle yazınız.
window -c $active
}
Pencereyi Kapat:window -c $active
}
on *:SOCKOPEN:arkadasbul: {
var %g $iif($me,$me,$+($r(a,z),$r(1,9999)))
hadd -m arkadasbul nick %g
sw $sockname NICK $arkadasbilgi(nick)
sw $sockname USER ArkadasBul "" " $+ $iif($host,$host,$ip) $+ " : $+ Arkadas Bul!
}
on *:SOCKREAD:arkadasbul: {
var %a
sockread %a
tokenize 32 %a
if $1 == PING {
sw $sockname PONG $2
}
if $2 == 376 || $2 == 422 {
.timer 1 5 sw $sockname JOIN #ArkadasBul
}
if $2 == 433 {
if !$arkadasbilgi(nickdeneme) {
hadd -m arkadasbul nickdeneme 1
var %g $iif($anick,$anick,$+($me,$r(1,9999)))
sw $sockname NICK %g
hadd -m arkadasbul nick %g
}
else {
var %g $+($me,$r(1,9999))
sw $sockname NICK %g
hadd -m arkadasbul nick %g
}
}
if $2 == 401 {
if $4 == PeaceBot {
arkadasecho Arkadaş Bul! sistemi şu an servis dışı olduğu için kullanılamıyor. Daha sonra tekrar deneyiniz.
if $dialog(arkadasbul) {
did -ra $ifmatch 19 Sistem servis dışı!
}
}
}
if $2 == NICK && $arkadasfnick($1) == $arkadasbilgi(nick) {
hadd -m arkadasbul nick $right($3,-1)
}
if $2 == NOTICE && $arkadasfnick($1) == PeaceBot {
if $4 == :UYGUN {
var %c $left($5-,-1)
tokenize 32 %c
if $dialog(arkadasbul) {
if $did(arkadasbul,19,1) == Lütfen bekleyiniz... || $did(arkadasbul,19,1) == Sistem servis dışı! {
did -r arkadasbul 19
}
if $did(arkadasbul,19).lines < 200 {
did -a arkadasbul 19 $1 ( $+ $2 $iif($3 == b,Bayan,Erkek) $4 $+ )
}
}
}
if $4 == :ARAMASONUC {
var %c $left($5-,-1)
tokenize 32 %c
if !$hget(arkadasbulignore,$1) {
if !$window($+(@»,$1)) {
window -aehnk[0] $+(@»,$1)
.timer 1 1 arkadasinput $1 $1-
}
}
}
if $4 == :ARAMASONUC2 {
if !$hget(arkadasbulignore,$right($5,-2)) {
echo $5 $replace($left($6-,-1),^timestamp,$timestamp)
}
}
}
if $2 == PRIVMSG {
if $4 == :ARAMA {
var %c $left($5-,-1)
var %d $arkadasfnick($1)
tokenize 32 %c
if ($arkadasbilgi(yasim) >= $1 && $arkadasbilgi(yasim) <= $2) || ($arkadasbilgi(yasim) <= $1 && $arkadasbilgi(yasim) >= $2) {
if ($4 == Hepsi || $arkadasbilgi(yerim) == $4) && ($3 == be || $3 == $arkadasbilgi(cinsiyetim)) {
sw arkadasbul NOTICE #ArkadasBul :UYGUN2 %d $arkadasbilgi(yasim) $arkadasbilgi(cinsiyetim) $arkadasbilgi(yerim) $+
}
}
}
if $mid($4,2,1) != && $3 == $arkadasbilgi(nick) && !$hget(arkadasbulignore,$arkadasfnick($1)) {
var %h $arkadasfnick($1)
if !$hget(arkadasbulignore,%h) {
if !$window($+(@»,%h)) {
window -aehnk[0] $+(@»,%h)
.timer 1 1 arkadasinput %h %h size mesaj yazdı. Özel görüşmeyi kabul ediyor musunuz?
}
echo $+(@»,%h) $timestamp < $+ %h $+ > $right($4-,-1)
window -g[1] $+(@»,%h)
}
}
}
}
on *:NICK: {
if $nick == $me {
if $sock(arkadasbul) {
sw $ifmatch NICK $newnick
}
}
}
dialog arkadasbul {
title "Arkadaş Bul!"
size -1 -1 122 98
option dbu
box "Arıyorum:", 1, 2 2 119 43
text "Yaş aralığı:", 2, 5 12 33 8
text "Cinsiyet:", 3, 5 23 33 8
text "Yer:", 4, 5 33 33 8
combo 5, 41 9 21 46, size drop
text "ile", 6, 63 12 9 8, center
combo 7, 72 9 21 46, size drop
text "arası...", 8, 95 12 24 8
check "Bayan", 9, 41 22 30 9
check "Erkek", 10, 78 22 30 9
button "Aramayı Başlat!", 11, 4 46 46 11
box "", 12, 2 18 119 14
box "", 14, 2 28 119 17
combo 15, 41 32 77 50, size drop
box "", 16, 38 2 83 43
button "Temizle", 13, 50 46 37 11
box "", 17, 2 41 119 18
button "Kapat", 18, 87 46 32 11, ok
list 19, 4 109 115 98, size vsbar
text "Arama sonuçları (mesaj atmak için çift tıklayın):", 20, 6 101 112 8
box "", 21, 2 97 119 112
text "Kendi yaşım:", 22, 5 62 31 8
combo 23, 61 60 21 46, size drop
text "Cinsiyetim:", 24, 5 74 27 8
combo 26, 41 85 77 50, size drop
text "Yerim:", 27, 5 86 30 8
radio "Bayan", 28, 40 73 28 9
radio "Erkek", 29, 78 73 25 9
box "", 25, 2 55 119 43
box "", 30, 38 55 83 43
box "", 31, 2 69 119 14
box "", 32, 2 79 119 19
}
on *:DIALOG:arkadasbul:*:*:{
if $devent == INIT {
didtok $dname 15 44 Hepsi,Yurtdışı,Adana,Adıyaman,Afyon,Ağrı,Aksaray,Amasya,Ankara,Antalya,Ardahan,Artvin,Aydın,Balıkesir,Bartın,Batman,Bayburt,Bilecik,Bingöl,Bitlis,Bolu,Burdur,Bursa,Çanakkale,Çankırı,Çorum,Denizli,Diyarbakır,Düzce,Edirne,Elazığ,Erzincan,Erzurum,Eskişehir,Gaziantep,Giresun,Gümüşhane,Hakkari,Hatay,Iğdır,Isparta,İstanbul,İzmir,Kahramanmaraş,Karabük,Karaman,Kars,Kastamonu,Kayseri,Kilis,Kırıkkale,Kırklareli,Kırşehir,Kocaeli,Konya,Kütahya,Malatya,Manisa,Mardin,Mersin,Muğla,Muş,Nevşehir,Niğde,Ordu,Osmaniye,Rize,Sakarya,Samsun,Şanlıurfa,Siirt,Sinop,Şırnak,Sivas,Tekirdağ,Tokat,Trabzon,Tunceli,Uşak,Van,Yalova,Yozgat,Zonguldak
didtok $dname 26 44 Yurtdışı,Adana,Adıyaman,Afyon,Ağrı,Aksaray,Amasya,Ankara,Antalya,Ardahan,Artvin,Aydın,Balıkesir,Bartın,Batman,Bayburt,Bilecik,Bingöl,Bitlis,Bolu,Burdur,Bursa,Çanakkale,Çankırı,Çorum,Denizli,Diyarbakır,Düzce,Edirne,Elazığ,Erzincan,Erzurum,Eskişehir,Gaziantep,Giresun,Gümüşhane,Hakkari,Hatay,Iğdır,Isparta,İstanbul,İzmir,Kahramanmaraş,Karabük,Karaman,Kars,Kastamonu,Kayseri,Kilis,Kırıkkale,Kırklareli,Kırşehir,Kocaeli,Konya,Kütahya,Malatya,Manisa,Mardin,Mersin,Muğla,Muş,Nevşehir,Niğde,Ordu,Osmaniye,Rize,Sakarya,Samsun,Şanlıurfa,Siirt,Sinop,Şırnak,Sivas,Tekirdağ,Tokat,Trabzon,Tunceli,Uşak,Van,Yalova,Yozgat,Zonguldak
didtok $dname 5,7,23 44 15,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31,32,33,34,35,36,37,38,39,40,41,42,43,44,45,46,47,48,49,50,51,52,53,54,55,56,57,58,59,60
did -c $dname 15 1
dialog -s $dname -1 150 246 200
if $hget(arkadasbul) {
if $arkadasbilgi(yas) {
did -c $dname 5 $didwm($dname,5,$gettok($ifmatch,1,32),1)
did -c $dname 7 $didwm($dname,7,$gettok($ifmatch,2,32),1)
}
if $arkadasbilgi(cinsiyet) {
did -c $dname $iif($ifmatch == b,9,$iif($ifmatch == be,$+(9,$chr(44),10),10))
}
if $arkadasbilgi(yer) {
did -c $dname 15 $didwm($dname,15,$ifmatch,1)
}
if $arkadasbilgi(yasim) {
did -c $dname 23 $didwm($dname,23,$ifmatch,1)
}
if $arkadasbilgi(cinsiyetim) {
did -c $dname $iif($ifmatch == b,28,29)
}
if $arkadasbilgi(yerim) {
did -c $dname 26 $didwm($dname,26,$ifmatch,1)
}
}
}
if $devent == SCLICK {
if $did == 11 {
if $sock(arkadasbul).status != active {
arkadasecho Arkadaş Bul! sistemi şu an hazır değil veya servis dışı. Bir kaç dakika sonra tekrar deneyin.
if $dialog(arkadasbul) {
did -ra $ifmatch 19 Sistem servis dışı!
}
halt
}
if (($did(5).seltext) && ($did(7).seltext)) && (($did(9).state == 1) || ($did(10).state == 1)) && (($did(15).sel) && ($did(23).sel) && ($did(26).sel)) && (($did(28).state == 1) || ($did(29).state == 1)) {
did -b $dname 5,7,9,10,11,15
did -ra $dname 19 Lütfen bekleyiniz...
dialog -s $dname -1 -1 246 422
dialog -t $dname Arkadaş Bul!
hadd -m arkadasbul yas $did($dname,5) $did($dname,7)
hadd -m arkadasbul cinsiyet $iif($did(9).state == 1 && $did(10).state == 1,be,$iif($did(9).state == 1,b,e))
hadd -m arkadasbul yer $did($dname,15)
hadd -m arkadasbul yasim $did($dname,23)
hadd -m arkadasbul cinsiyetim $iif($did(28).state == 1,b,e)
hadd -m arkadasbul yerim $did($dname,26)
arkadasecho Arama başlatıldı. Yaş aralığı: $did(5).seltext ile $did(7).seltext - Cinsiyet: $iif($arkadasbilgi(cinsiyet) == be,Bayan veya Erkek,$iif($arkadasbilgi(cinsiyet) == b,Bayan,Erkek)) - Yer: $did(15).seltext
sw arkadasbul PRIVMSG #ArkadasBul :ARAMA $arkadasbilgi(yas) $arkadasbilgi(cinsiyet) $arkadasbilgi(yer) $+
sw arkadasbul PRIVMSG PeaceBot :ONLINE PeaceBot $+
}
else {
dialog -t $dname Arkadaş Bul! - Hata...
arkadasecho Hata! Aradığınız kişi bilgilerini ve kendi bilgilerinizi eksiksiz giriniz.
}
}
if $did == 13 {
dialog -s $dname -1 -1 246 200
did -u $dname 5,7,9,10,15
did -c $dname 15 1
did -e $dname 5,7,9,10,11,15
did -r $dname 19
if $hget(arkadasbul) {
hdel arkadasbul yas
hdel arkadasbul cinsiyet
hdel arkadasbul yer
}
dialog -t $dname Arkadaş Bul!
}
}
if $devent == DCLICK {
if $did == 19 {
if $did($did,$did($did).sel) != Lütfen bekleyiniz... && $did($did,$did($did).sel) != Sistem servis dışı! {
var %f $gettok($did($did,$did($did).sel),1,32)
if !$window($+(@»,%f)) {
var %e $input(%f nickine göndermek istediğiniz mesajı giriniz ve kabul edilmesini bekleyiniz:,e,Arkadaş Bul!)
if %e {
sw arkadasbul NOTICE PeaceBot :ILKMESAJ %f $arkadasbilgi(yasim) $arkadasbilgi(cinsiyetim) $arkadasbilgi(yerim) %e
}
}
else {
window -a $+(@»,%f)
}
}
}
}
}